Stiffy Makane: Apocolocyntosis — 146 of 235

Part Two - "The Golden Ass"

Outside_Shipboard is a region. Poop_Deck2, Main_Deck, Halfway Up the Mast, and Crow's Nest are rooms in Outside_Shipboard. The scenery_ship_deck is in Poop_Deck2 and Main_Deck.

Cabin Hallway, Stiffy's Cabin, and the Hold are rooms in Shipboard. Outside_Shipboard is in Shipboard.

The becalmed_sky_scenery is sky_scenery in Outside_Shipboard. It is in Main_Deck, Halfway Up the Mast, and Crow's Nest. The description is "A hot yellow sun beats down from a blue, cloudless, windless sky." Understand "hot", "yellow", "sun" , "blue", "cloudless", "sky", and "windless" as the becalmed_sky_scenery.

Poop_Deck2 is a room. The printed name is "Poop Deck". The description is "This is the poop deck of [italic type]The Golden Ass[roman type], your father's pride and joy. One of the first ships in his merchant fleet, it is one of the smaller ones now, but the most luxuriously appointed. A hatch [if Cabin Hatch is open](open) allows[otherwise](closed) blocks[end if] access to the cabins below. The main deck is to the fore."

Instead of shitting in Poop_Deck2, say "Oddly enough, you[apostrophe]re not supposed to poop on the Poop Deck. It's not fair at all."

The cabin hatch is a door. It is openable and open. It is down from Poop_Deck2. It is scenery. The description is "This is a sturdy wooden hatch, which keeps the rain out of the cabins, but allows access via a ladder. It is [if Cabin Hatch is open]open[otherwise]closed." Understand "sturdy", "wooden", "ladder", and "access" as the cabin hatch.

Cabin Hallway is down from Cabin Hatch. The description is "This is a cramped hallway. The sailors['] quarters are fore, the captain's quarters are aft, your cabin is to starboard, and Palinurus lives in the cabin to port."

Instead of going fore in Cabin Hallway:

if the global_pirate_attack_flag is 3, instead say "The door is barred from the other side.";

say "The last time you went in there, it smelled of moldy sweatsocks, and the men made it very clear that you, as a member of the officer class, were not welcome."

Captain's door is a door. It is scenery. Captain's door is aft from Cabin Hallway. It is closed. It is locked. The description is "The door to the captain's quarters is made of thick planks of beech. It is closed." Understand "thick", "plank", "planks", "beech", "aft", and "captain" as Captain's door.

Palinurus's door is a door. It is scenery. Palinurus's door is port from Cabin Hallway. It is closed. It is locked. The description is "The door to Palinurus's quarters is closed. It is made of gray, weathered wood." Understand "wood", "gray", "weathered", and "port" as Palinurus's Door.

Stiffy's door is a door. It is scenery. It is starboard of Cabin Hallway. It is open. It is openable. The description is "The door to your quarters is a flimsy thing, made from cheap pine. It is [if Stiffy's door is open]open[otherwise]closed[end if]." Understand "pine", "cheap", "flimsy", "my", and "starboard" as Stiffy's Door. It is lockable. It is unlocked. Instead of locking Stiffy's door with [S - something], say "Unfortunately, the door doesn't lock, which has been the source of a bit of embarassment." Before Closing Stiffy's door:

if the location is Stiffy's Cabin and the location of the Pirate Captain is Cabin Hallway

begin;

say "The pirate captain effortlessly blocks the slamming door with his shiny boot. He grins.";

stop the action;

end if.

Stiffy's Cabin is a room. It is starboard of Stiffy's door. The description is "This is your cabin. There's nothing much in it beyond a hammock and a porthole."

The hammock is a supporter in Stiffy's Cabin. It is scenery. The description is "The hammock swings gently to and fro."

The porthole is scenery in Stiffy's Cabin. The porthole can be openable. It is openable. The porthole can be open. It is closed. The description is "[if the porthole is open]Salty air wafts in from the open porthole[otherwise]The porthole, a thick disc of glass, is closed[end if]." Understand "thick", "disc", "nine", "inch", "nine-inch", "hole", "disk", and "glass" as the porthole. The porthole can be enterable. It is enterable. Instead of entering the porthole, say "Unfortunately, you are much too large to fit through a nine-inch porthole."

Instead of smelling when the location is Stiffy's Cabin:

if the porthole is open

begin;

say "The open porthole admits clean, salty-smelling sea air.";

otherwise;

say "The room has the unmistakable funk of a thoroughly-lived-in ship's cabin.";

end if.

Main_Deck is fore of Poop_Deck2. The printed name is "Deck". The description is "The mast ascends from here, and the poop deck is aft. A hatch [if Hold Hatch is open](open) allows[otherwise](closed) blocks[end if] access to the hold below."

The scenery_mast is a backdrop in Main_Deck. It is in Halfway Up the Mast and Crow's Nest. The description is "The mast is cut from the trunk of a great pine tree. Spikes hammered into it provide a crude ladder." Understand "mast", "pine", "trunk", "spikes", "hammered", "crude", "ladder", and "great" as the scenery_mast. The printed name is "mast". Instead of climbing the scenery_mast:

if the location is the Crow's Nest, instead try going down;

if the location is Main_Deck, instead try going up;

say "You could climb either up or down from here."

The scenery_sea is a backdrop in Main_Deck. The scenery_sea can be enterable. It is enterable. It is in Halfway Up the Mast, Crow's Nest, and Poop_Deck2. The description is "The blue sea stretches endlessly in all directions[if the pirate clock > 5 and the pirate clock < 10 ], with a sleek black ship approaching from the south[end if][if the pirate clock > 9 and the pirate clock < 15],with a ship drawing quite near to the south[end if][if the pirate clock > 14],and a pirate ship is immediately alongside [italic type]The Golden Ass[roman type][end if]." Understand "blue", "sea", "ocean", "Mediterranean", "horizon", "endless", "endlessly", and "water" as the scenery_sea. Instead of entering the scenery_sea, follow the poor-Ophelia rule. Instead of jumping into the scenery_sea, try entering the scenery_sea. Instead of jumping in Halfway Up the Mast, try entering the scenery_sea. Instead of jumping in the Crow's Nest, try entering the scenery_sea.

The far_scenery_ship is scenery in the Crow's Nest. The description is "A black ship is visible far to the south, approaching fast." Understand "black", "pirate", "ship", "sleek", "apporaching", "closing", "fast" as the far_scenery_ship.

The scenery_pirate_ship is a backdrop. The description is "[if the pirate clock < 10]A pirate ship is barely visible to the south, but it is closing fast[end if][if the pirate clock > 9 and the pirate clock < 15]The sleek, black pirate ship is approaching swiftly from the south[end if][if the pirate clock > 14]The sleek, black pirate ship, bristling with oars, floats alongside [italic type]The Golden Ass[roman type][end if]." Understand "sleek", "black", "closing", "fast", "approaching", "pirate", "ship", "bristling", "oar", and "oars" as the scenery_pirate_ship. The printed name is "pirate ship". instead of doing anything other than examining with the scenery_pirate_ship:

if the pirate clock < 15

begin;

say "The pirate ship has not arrived yet.";

otherwise;

say "The less attention you are seen paying it, the better.";

end if.

This is the poor-Ophelia rule:

if the scenery_sea is not warned_about

begin;

now the scenery_sea is warned_about;

say "You'd certainly drown if you leapt into the sea. You're not that good a swimmer, and you're a very long way from land.";

otherwise;

say "You leap into the waves, and they close overhead with a little splash. You sink like a stone.";

end the story saying "You have drowned yourself";

end if.

The hold hatch is a door. It is openable and open. It is down from Main_Deck. It is scenery. The description is "This is a sturdy wooden hatch, which keeps the rain out of the hold, but allows access via a ladder. It is [if Hold Hatch is open]open[otherwise]closed." Understand "sturdy", "wooden", "ladder", and "access" as the hold hatch.

Hold is down from the hold hatch. The description is "This is the hold of the ship. It contains crates of foodstuffs, barrels of water, and a few dozen amphorae of olive oil. A ladder leads up to [if the Hold Hatch is open]the deck[otherwise]a closed hatch[end if]." Before going inside in the Hold:

if the water_barrel is in the Hold, instead try entering the water_barrel.

Some crates are scenery in the Hold. The description is "Closed crates of dried meat, fruits, and flour; these are the rations for the crew during the voyages of [italic type]The Golden Ass[roman type]." They are openable. Some crates can be open. Some crates can be openable. They are closed. Instead of opening the crates, say "You lack a suitable instrument, and don't really want to open the crates anyway." Instead of climbing the crates, say "This is not, in fact, a first-person shooter, in which you might conceivably derive some tactical advantage from climbing onto the crates." Instead of doing anything other than opening, climbing, or examining with the crates, say "The crates are too big to move, and fundamentally uninteresting." Understand "dried", "meat", "closed", "fruit", "fruits", "flour", "uninteresting", "big" as the crates.

Some barrels of water are scenery in the Hold. Some barrels of water can be open. Some barrels of water can be openable. Does the player mean doing something with the barrels of water: it is unlikely. The description is "These are sealed barrels of water for the crew's use." They are openable. They are closed. Instead of opening the barrels, say "You lack both the tools and the motivation." Understand "barrel" as barrels of water. After examining the barrels of water for the first time:

say "One barrel has been opened; its lid sits slightly askew.";

move the water_barrel to the Hold.

Understand "sealed" as barrels of water. Instead of doing anything other than opening, climbing, or examining with the barrels of water, say "The barrels are too big to move, and fundamentally uninteresting." Instead of climbing the barrels of water, say "There is no need to climb on the barrels." Instead of rolling the barrels of water, say "Roll out the barrel, and we'll have a barrel of...no."

The water_barrel is an open container. The water_barrel can be drinkable. It is drinkable. The water_barrel can be enterable. It is enterable. The printed name is "opened barrel of water". The initial appearance is "A half-full barrel of water , its lid ajar, rests heavily on the floor here." The description is "The barrel of water is about half-full." Does the player mean doing something with the water_barrel: it is likely. Understand "water", "barrel", "opened", "open", "half-full", "half-empty", "tepid" as the water_barrel. After entering the water_barrel:

say "The water rises amost to your nose as you balance the lid atop your head, leaving yourself just a crack from which to peer out."

Instead of tasting or drinking the water_barrel, say "The water is tepid and tasteless." Instead of doing anything other than closing, opening, examining, climbing, tasting, drinking, or entering with the water_barrel, say "The barrel is effectively fixed in place, and too large to do much of anything with." Instead of climbing the water_barrel, say "The lack of a sturdy lid would make that problematic."

Instead of closing the water_barrel, say "You can't really do much better than putting the lid loosely on top of the barrel."

Instead of opening the water_barrel, say "It's already open."

Instead of rolling the water_barrel, say "Roll out the barrel, and we'll have a barrel of...no."

Some amphorae are scenery in the hold. Some amphorae can be open. Some amphorae can be openable. They are closed. The description is "A few dozen sealed terracotta amphorae, each containing about ten gallons of olive oil." Understand "amphora", "olive", "oil", "terracotta", "dry", "clay", "sealed", "ten", "gallon", "gallons", and "ten-gallon" as the amphorae. Instead of opening the amphorae, say "The amphorae are sealed." Instead of doing anything other than smelling, opening or examining with the amphorae, say "The amphorae are too big to easily handle." Instead of smelling the amphorae, say "The amphorae do not smell of olive oil, but instead of dry clay." Instead of rolling the amphorae, say "Roll out the amphora, and we'll have an amphora of...wait, what? No."

Instead of going up when the player is in the water_barrel, try exiting.

Halfway Up the Mast is up from Main_Deck. The description is "The mast descends to the deck, and ascends to the Crow's Nest. Around you the sea stretches endlessly in all directions. The sails hang limp; there is no breeze."

The sails are a backdrop in Halfway Up the Mast. They are in Main_Deck, Poop_Deck2, and Crow's Nest. The description is "The sails are limp in the calm." Understand "sail", "limp", "limply", "rigging", and "canvas" as the sails. Instead of doing anything other than climbing or examining with the sails, say "The sails are out of reach." Instead of climbing the sails, say "You lack the dexterity to scramble up the rigging as you have seen the sailors do."

Crow's Nest is up from Halfway Up The Mast. The description is "This is the crow's nest. You can climb back down the mast to the deck. In all directions, the sea stretches without end, unbroken from horizon to horizon[if the pirate clock < 10]. A ship is approaching at some distance from the south[end if][if the pirate clock > 9 and the pirate clock < 15]. A black ship is drawing close[end if][if the pirate clock > 14]. A black pirate ship rides alongside [italic type]The Golden Ass[roman type][end if]."

A terrified crewman is a man in Crow's Nest. The description is "A terrified sailor quakes with fear." Understand "sailor", "lookout", "gibbering", "scared", "quaking", and "fearful" as the terrified crewman. Instead of doing anything other than examining with the terrified crewman, say "The crewman whimpers with fear and bats you away." The terrified crewman is unspeakable. The default reply of the terrified crewman is "The sailor is too scared to do anything but gibber."