Stiffy Makane: Apocolocyntosis — 62 of 235

Section Two - "Festus"

Festus is a man in the privy. The description is "Festus is your usually-cheery slave. He has dirty blond hair, and is a couple inches shorter than you are. He's usually found wearing a goofy grin. Prone to laziness and drunkenness, he floats along through life guided by his gonads. His cock is just slightly smaller than yours, and, with that fact plus his tendency towards debauchery, he makes the perfect wingman." Understand "blond", "slave", "dirty", "lazy", "wingman", "drunk", "drunken", and "goofy" as Festus. The conversation of Festus is the Table of Festus's Chatter.

Instead of smelling Festus, say "Festus smells better than he looks like he should; musk and sweat, but clean, fresh sweat. He's obviously bathed recently."

Festus's mouth is part of Festus. The description is "Festus's mouth is more talented than it looks. Mostly it looks like crooked teeth and a goofy grin." Understand "teeth", "lips", "crooked", and "grin" as Festus's mouth.

Instead of kissing Festus:

if Stiffy Makane is filthy, instead try fucking Festus;

if the location is the Tablinum

begin;

say "Your father glares. 'Why don't you two get a room? A different room. Not the room in which I'm working.'";

otherwise;

say "You make out with Festus for a while. He needs to brush his teeth.";

end if.

Instead of fucking Festus:

if the stiffycock is held by the player

begin;

if Stiffy Makane is filthy, instead say "Festus dodges your advances. 'Dude, you're covered in shit!' he screams. 'Not until you take a bath, I won't!'";

if Festus is unboinked

begin;

if the location is the Tablinum

begin;

say "Your father glares. 'Why don't you two get a room? A different room. Not the room in which I'm working.'";

otherwise;

say "Festus obligingly flips up his tunic, braces himself against [if the location is the peristyle]one of the portico columns[end if][if the location is the atrium]the nearest wall[end if][if the location is the Stiffy Love Nest]the nightstand[end if], and presents his ass to you. You spit on your hand, moisten your cock, and ram it in.[paragraph break]";

say "It's sort of like wandering alone through the Colosseum[51 as a reference].[paragraph break]";

say "Festus apologetically mutters, 'Your dad really stretched me out this morning. Here, let me help.'[paragraph break]";

say "He reaches back and makes a circle with his thumb and forefinger around your cock, and with his digital ministrations as well as his cavernous ass, you eventually achieve an orgasm. A pretty unsatisfying one as orgasms go, but better than nothing.";

record "Festus" as achieved;

now Festus is boinked;

end if;

otherwise;

say "Been there, done that[if the location has not been Poop Deck]. Today, even[end if].";

end if;

otherwise;

say "You are not undressed for the occasion.";

end if.

Instead of fucking Festus's mouth:

if the stiffycock is held by the player

begin;

if Stiffy Makane is filthy, instead try fucking Festus;

if Festus is unboinked

begin;

if the location is the Tablinum

begin;

say "Your father glares. 'Why don't you two get a room? A different room. Not the room in which I'm working.'";

otherwise;

say "Festus obligingly drops to his knees and begins bobbing up and down on your cock. He's had a lot of practice with you, and knows just when and where to use his tongue, teeth, and epiglottis. It's not long at all before you groan and deliver what feels like a quart of semen deep into his throat.[paragraph break]";

say "Festus gulps, wipes your dick on his tunic, grins broadly, and belches delicately. 'A pleasure, as always, master,' he croons.";

record "Festus" as achieved;

now Festus is boinked;

end if;

otherwise;

say "Been there, done that[if the location has not been Poop Deck]. Today, even[end if].";

end if;

otherwise;

say "You are not undressed for the occasion.";

end if.

Instead of touching, rubbing, sucking, blowing, or wanking off Festus, say "Festus stops you. 'Sorry, Stiffy,' he explains, 'but your dad's left me pretty drained. Maybe later, OK?'"

Instead of asking Festus about "blow/blowjob", try fucking Festus's mouth.

Instead of asking Festus about "blow job", try fucking Festus's mouth.

Before asking Festus about anything when Festus is in the privy and the player is in the peristyle:

say "A muffled voice shouts from the privy: '[italic type]Busy![roman type] Wait till I'm done!'";

stop the action.

Instead of asking Festus about "toga", follow the toga replacement rule.

Instead of giving or showing the toga to Festus, follow the toga replacement rule.

Instead of showing the invitation token to Festus, say "Festus smiles. 'Cool. That'll be fun.'"

Instead of giving the invitation token to Festus, say "Festus shakes his head. 'You carry it; that'll get us both in.'"

Instead of giving or showing something to Festus, say "Festus stares at [the noun] blankly. 'Why don't you hang on to it for now?' he asks."

This is the toga replacement rule:

If Stiffy Makane is filthy

begin;

say "Festus stares at you. 'Dude, you're covered in shit. If you put on a fresh toga, then [italic type]it[roman type] will be covered in shit too. Just head down to the baths and clean up. They'll do your laundry there too, you know.'";

stop the action;

end if;

If the toga is not visible

begin;

say "Festus grins. 'What, lost it again? Dumbass. Hang on. I'll have a new one for you in a jiffy.'";

follow the toga_replacement rule;

otherwise;

if the toga is not filthy

begin;

say "Festus shrugs. 'Doesn't look like it needs laundering to me.'";

otherwise;

say "Festus grimaces with disgust at the sight of the toga. 'Yuck,' he nods, taking it from you. 'Be right back.'";

follow the toga_replacement rule;

end if;

end if.

This is the toga_replacement rule:

say "Festus disappears into the house and returns almost immediately with a clean toga, which he helps you into.";

now the toga is cleanish;

now the toga is held by the player;

really have the parser notice the toga;

try wearing the toga.

Table of Festus's Chatter