Stiffy Makane: Apocolocyntosis — 208 of 235

Part Four - "Ulpia"

The scullery maid is a woman on the filthy mattress. The description is "[The scullery maid] peers blearily around. Her face is smeared with dirt, her hair is tangled and matted, and she reeks of cheap wine. She [if a garment is worn by the scullery maid]wears [a random garment worn by the scullery maid][otherwise]is naked[end if]." She is not proper-named. The printed name is "scullery maid". Understand "tousled", "sprawling", "smeared", "woman", "girl", "scullery", "maid", "slattern", "slatternly", "dirty", "grubby", "drunk", "drunken", "slut", "lazy", and "sous-chef" as the scullery maid. Does the player mean doing something with the scullery maid: it is likely. Instead of smelling the scullery maid, say "She smells of dirt and cheap wine." Understand "Ulpia" as the scullery maid when the scullery maid is proper-named. The default reply of the scullery maid is "[The scullery maid] blinks owlishly and uncomprehendingly." The conversation of the scullery maid is the Table of Ulpian Chatter.

Before asking the scullery maid about something:

if the topic understood matches "Ulpia/maid/sous-chef/drunk/drunken/lazy/slattern/scullery/slut", replace the topic understood with "herself";

if the topic understood matches "scullery maid", replace the topic understood with "herself";

if the topic understood matches "lazy slut", replace the topic understood with "herself";

if the topic understood matches "herself" and the scullery maid is not proper-named

begin;

now the scullery maid is proper-named;

now the printed name of the scullery maid is "Ulpia";

end if.

Instead of kissing the scullery maid:

say "[The scullery maid] kisses you vigorously. She tastes of sour wine."

Instead of fucking the scullery maid:

if the scullery maid is boinked

begin;

say "[The scullery maid] writhes langorously, and says, 'I think I'm done for now, thanks.'";

otherwise;

if the stiffycock is not visible

begin;

say "'Aren't you a little overdressed?' asks [the scullery maid].";

otherwise;

if a garment is worn by the scullery maid

begin;

say "'Aren't I a little overdressed?' asks [the scullery maid].";

otherwise;

say "'Do me doggy-style!' squeaks [the scullery maid], assuming the appropriate position. You [run paragraph on]";

if the player is not on the filthy mattress

begin;

say "drop [run paragraph on]";

otherwise;

say "get [run paragraph on]";

try silently exiting;

end if;

say "to your knees behind her and thrust into her moist pussy. Of all the times you've ever boned a slatternly servant on a reeking mattress, this is certainly one of them. Both of you reach a moderately satisfying climax at about the same time, and she giggles as you wipe your dick [run paragraph on]";

if the grubby tunic is visible

begin;

say "on her tunic before you toss it back to her [run paragraph on]";

now the grubby tunic is worn by the scullery maid;

otherwise;

say "in her greasy hair [run paragraph on]";

end if;

say "and stand up.";

record "Ulpia" as achieved;

now the scullery maid is boinked;

end if;

end if;

end if.

The grubby tunic is a garment worn by the scullery maid. The description is "The tunic is stained with grime and splashed wine." Understand "crusty", "dirty", "filthy", "grimy", "wine", "splash", "splashed", "stained", "stains", and "nasty" as the grubby tunic.

This is the fancy-removing rule:

if the noun is the grubby tunic, continue the action;

if the noun is the simple white tunic, continue the action;

if the noun is the golden sandals, continue the action;

abide by the can't remove from people rule.

The fancy-removing rule is listed instead of the can't remove from people rule in the check removing it from rulebook.

Before taking the grubby tunic:

if the grubby tunic is worn by the scullery maid

begin;

if the scullery maid is unboinked

begin;

say "[The scullery maid] nods enthusiastically. 'Here, let me help you with that,' she says, shrugging out of the tunic.";

now the grubby tunic is held by the player;

stop the action;

otherwise;

say "[The scullery maid] smiles, but resists your attempts to undress her.";

stop the action;

end if;

end if.

Before taking off the grubby tunic:

if the grubby tunic is worn by the scullery maid, instead try silently taking the grubby tunic.

Before removing the grubby tunic from the scullery maid:

instead try silently taking the grubby tunic.

Instead of giving the grubby tunic to the scullery maid:

if the scullery maid is boinked

begin;

say "'Thanks,' says [the scullery maid], as she slips the tunic back on.";

now the grubby tunic is worn by the scullery maid;

otherwise;

say "'Thanks,' says [the scullery maid], 'but we have some unfinished business.' She drops the tunic on the floor.";

move the grubby tunic to the location;

end if.

Instead of showing the grubby tunic to the scullery maid:

if the scullery maid is boinked, instead try giving the grubby tunic to the scullery maid;

say "'Thanks,' says [the scullery maid], 'but we have some unfinished business.'"

The scullery maid's hair is part of the scullery maid. The description is "Ratty dark-brown hair is tangled around [the scullery maid]'s head." Understand "ratty", "brownish", "dark", "brown", and "dark-brown" as the scullery maid's hair. Instead of smelling the scullery maid's hair, try smelling the scullery maid.

The scullery maid's lips are part of the scullery maid. The description is "[The scullery maid]'s lips are narrow and pink." Understand "narrow", "pink", "lip", and "mouth" as the scullery maid's lips. Instead of kissing or sucking the scullery maid's lips, try kissing the scullery maid.

The scullery maid's eyes are part of the scullery maid. The description is "[The scullery maid] has bloodshot, bleary, black, beady eyes." Understand "eye", "black", "blood", "bloodshot", "bloody", "bleary", and "beady" as the scullery maid's eyes.

The scullery maid's nose is part of the scullery maid. The description is "[The scullery maid]'s nose is thin and sharply-pointed." Understand "thin", "sharply", "sharply-pointed", and "pointed" as the scullery maid's nose. Instead of fucking, sucking, or blowing the scullery maid's nose, say "'Eeeagh!' she shrieks, swatting you away."

The scullery maid's tits are things. The description is "She has small but shapely tits surmounted by pink nipples." Understand "chest", "small", "shapely", "nipple", "nipples", "breast", "tit", "breasts", "hooter", "hooters", "boob", "pink", and "boobs" as the scullery maid's tits. Instead of fucking the scullery maid's tits:

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

say "'They're too small. It'll never work,' [the scullery maid] says. She's right."

Instead of touching, rubbing, sucking, or blowing the scullery maid's tits, say "[The scullery maid] writhes and moans, and then suggests, 'Just put it in already!'"

Instead of smelling the scullery maid's tits, try smelling the scullery maid.

The scullery maid's pussy is a vagina. It is part of the scullery maid. The description is "Her pussy is covered in wiry black hair. Her inner labia are protuberant and chewed-looking." Instead of touching, rubbing, sucking, kissing, wanking off, or blowing the scullery maid's pussy, try touching the scullery maid's tits. Instead of smelling the scullery maid's pussy for the first time, say "Phew! You won't be doing that again." Instead of smelling the scullery maid's pussy, say "Once was plenty." Understand "wiry", "dark", "black", "curly", "pubic", "pubes", "public hair", "labia", "chewed", "chewed-looking", "protuberant", and "inner" as the scullery maid's pussy.

The scullery maid's asshole is an anus. It is part of the scullery maid. The description is "Her anus is tucked away underneath her. You can't reach it. Given the way the rest of her smells, probably just as well, really." Instead of doing anything other than examining with the scullery maid's asshole, try examining the scullery maid's asshole.

The scullery maid's legs are part of the scullery maid. The description is "Her legs are muscular, although dirty and scratched." Understand "thigh", "thighs", "calf", "calves", "feet", "foot", "muscular", "dirty", and "scratched" as the scullery maid's legs. Instead of kissing, touching, rubbing, sucking, or blowing the scullery maid's legs, say "[The scullery maid] regards you curiously. 'Not really my kink,' she opines, 'but if it makes you happy, feel free, I guess.'" Instead of smelling the scullery maid's legs, try smelling the scullery maid.

Before asking the scullery maid about something:

if the scullery maid is boinked

begin;

if the topic understood matches "door/key/stout/barred/cellar", replace the topic understood with "#fake1";

if the topic understood matches "wine cellar", replace the topic understood with "#fake1";

end if;

if the topic understood matches "#fake1" and the scullery maid is not warned_about

begin;

now the scullery maid is warned_about;

say "[The scullery maid] nods. 'Well, you [italic type]have[roman type] pleased me. So I'll let you have the key.' She langorously reaches for a brick on the floor near her bed, which turns out to be loose. She flicks a small bronze key from underneath it. The key skitters on the ground.";

move the cellar key to the location;

stop the action;

end if;

if the topic understood matches "#fake1", replace the topic understood with "key".

Table of Ulpian Chatter