Stiffy Makane: Apocolocyntosis — 143 of 235

One of the Bruces and Drunken Bastard

Release 1

Part Six - "North Shore and Shrine"

The North Shore of the Lake is a room. It is north of the North End of the Lake. "Jungle-covered hills rise to the north and west. To the east, a track follows the stream that feeds the lake to your south." Instead of going north in the North Shore of the Lake, try entering the dense jungle. Instead of going west in the North Shore of the Lake, try entering the dense jungle.

Before going south in the North Shore of the Lake:

now the encumbered action is "swimming";

follow the jungle encumbrance rule;

if rule failed, stop the action.

The Rocky Streambed is east of the North Shore of the Lake. "The trail from the west ends here at a sheer rock wall to the north, into which is cut a series of shallow handholds, like a ladder. To the south across the stream, the canyon wall rises vertically, and there are no obvious handholds. Farther east, the stream rises in a series of cataracts." Instead of going south in the Rocky Streambed, say "The walls of the canyon are too steep to climb." Instead of going east in the Rocky Streambed, say "Even a salmon would have difficulty ascending these rapids." Instead of going up in Rocky Streambed, try going north. Before going north in Rocky Streambed:

now the encumbered action is "climbing";

follow the jungle encumbrance rule;

if rule failed, stop the action;

say "You gingerly climb the slick, ladder-like surface. The ascent is very, very long, perhaps a thousand feet, and although the climb becomes a little less steep after the first few dozen feet, it is still a terrifying ordeal."

The scenery_stream2 is scenery in Rocky Streambed. The description is "The stream is about fifty feet wide but only a few feet deep here, with a silty bottom and a swift current." Understand "stream", "creek", "fifty", "feet", "fast", "fast-moving", and "water" as the scenery_stream2. The printed name is "stream". The scenery_stream2 can be enterable. It is enterable. Instead of jumping over the scenery_stream2, say "It's too wide to jump". Instead of swimming around in the scenery_stream2, try entering the scenery_stream2. Instead of jumping into the scenery_stream2, try entering the scenery_stream2. Instead of tasting the scenery_stream2, say "The water is clear, cold, and refreshing." Instead of smelling the scenery_stream2, say "The stream smells like fast-moving, aerated water." Instead of taking the scenery_stream2, say "You splash some water on yourself. It chills and refreshes you." Instead of listening to the scenery_stream2, say "The creek splashes noisily as it tumbles off the rocks to the east.." Instead of entering the scenery_stream2:

now the encumbered action is "swimming";

follow the jungle encumbrance rule;

if rule failed, stop the action;

say "You only get about ten feet into the stream before the swift-moving current carries you back out into the lake.";

move the player to the North End of the Lake.

Some scenery_cataracts are scenery in Rocky Streambed. They are ambiguously plural. The description is "The water leaps merrily over a series of cataracts to the east." The printed name is "cataracts". Instead of listening to the scenery_cataracts, say "The rapids chatter merrily." Instead of doing anything other than examining, listening, swimming around in, jumping into, diving into, jumping over, or entering with the scenery_cataracts, say "The cataracts are unapproachable due to the swiftness of the current." Understand "waterfall", "cataract", "cataracts", "rapid", "rapids", "chatter", "chattering", "merry" and "merrily" as the scenery_cataracts. The scenery_cataracts can be enterable. The scenery_cataracts are enterable. Instead of jumping over the scenery_cataracts, try going east. Instead of entering the scenery_cataracts, try going east. Instead of jumping into the scenery_cataracts, try going east. Instead of swimming around in the scenery_cataracts, try going east. Instead of diving into the scenery_cataracts, try going east.

The scenery_canyon is scenery in Rocky Streambed. The description is "The canyon rises vertically to north and south. A series of handholds forming a sort of ladder has been carved into the north wall, but the south is bare and sheer. It is black stone, slippery with moisture." The printed name is "canyon". Understand "canyon", "wall", "walls", "north", "south", "vertical", "vertically", "ladder", "steep", "handhold", "stair", "staircase", "stairway", "steps", "step", "handholds", "shallow", "series", "cut", "carved", "carven", and "chasm" as the scenery_canyon. The scenery_canyon can be enterable. It is enterable. Instead of entering the scenery_canyon, try going north. Instead of climbing the scenery_canyon, try going north.

The Plateau is north of the Rocky Streambed. "This is a small mesa of rock. Cliffs fall away on all sides, although the path leading to the carved staircase is barely visible to the south. One huge, leaning banana tree, glowing a soft gold in the sunlight, arches out over a terrible drop to the east."

Before going south in the Plateau:

now the encumbered action is "climbing";

follow the jungle encumbrance rule;

if rule failed, stop the action;

say "Lowering yourself over the edge of the cliff to find the first few footholds is one of the hardest things you've ever done, but after that it's just a matter of climbing slowly and deliberately and looking only at the wall in front of your face."

Instead of going north in the Plateau, try entering the scenery_void. Instead of going west in the Plateau, try going north. Instead of going up in the Plateau, try going east. Instead of going down in the Plateau, try going south.

Before going east in the Plateau:

if the baboon clock is 0, instead say "The troupe of baboons cluster into a snarling mass between you and the tree, preventing you from approaching.";

follow the jungle encumbrance rule;

if rule failed, stop the action.

Instead dropping a jungle yummy when the location is the Plateau:

try giving the noun to the baboons instead.

Some baboons are animals in the Plateau. The initial appearance is "A troupe of skinny, snarling baboons, their hindquarters a gaudy red and blue, [if the baboon clock is greater than zero]fight viciously among themselves for control of [the baboon disputation item][otherwise]watch you warily and hungrily[end if]." The description is "A troupe of hungry-looking baboons [if the baboon clock is greater than zero]savagely attack one another, fighting for possession of [a baboon disputation item][otherwise]glare at you with barely-repressed hostility[end if]." They are unspeakable. Understand "baboon", "monkey", "ape", "apes", "monkeys", "devil", "devils", "hostile", "glaring", "hungry", "hungrily", "skinny", "lean", "underfed", "snarling", "snarl", "wary", "warily", "troupe", and "vicious" as the baboons. The default reply of the baboons is "The baboons snarl fiercely, but make no other reply." Instead of kissing, touching, rubbing, or wanking off the baboons, say "The baboons draw away from your touch, snarling." Instead of fucking or buggering the baboons, say "You are not undressed for the occasion." [1] The baboons have a virginity. The baboons are unboinked. [2]

Before giving or showing something to the baboons:

if the noun is a jungle yummy

begin;

say "A baboon snatches [the noun] from you and hoots. Other baboons investigate. A fight breaks out over the delicious [noun].";

now the baboon clock is 1;

now the baboon disputation item is the noun;

move the noun to Limbo;

really have the parser notice the baboons;

otherwise;

say "A baboon snatches [the noun] from you, sniffs it suspiciously, curls its lip at you, showing great yellow teeth, and tosses it over the edge of the plateau.";

move the noun to Limbo;

really have the parser notice the baboons;

end if;

stop the action.

Some baboon anuses are anuses. They are part of the baboons. They are ambiguously plural. The description is "Each baboon's rear is a psychedelic landscape of red and blue." Understand "ass", "asshole", "gaudy", "hindquarters", "sphincter", "arsehole", "arse", "butt", "butthole", "bunghole", "buttock", "buttocks", "red", "blue", "psychedelic", "landscape", "rear", and "rectum" as the baboon anuses.

The scenery_banana_tree is scenery in the Plateau. The description is "The great banana tree describes a gentle arc to the east, arching out over the void. It is easily thick enough to bear your weight, and after the first few feet you could probably just walk along the trunk without needing to use your hands at all." Understand "banana", "tree", "arc", "gentle", "wide", "trunk", "great", "large", "thick", and "plant" as the scenery_banana_tree. The printed name is "banana tree". Instead of climbing the scenery_banana_tree, try going east. The scenery_banana_tree can be enterable. It is enterable. Instead of entering the scenery_banana_tree, try going east.

Instead of jumping in Up A Tree, try entering the scenery_void.

The scenery_baboons are a backdrop in Up A Tree. The description is "[baboon details]". Instead of doing anything other than examining with the scenery_baboons, say "The baboons are too far away." The printed name is "baboons". Understand "baboon", "baboons", "monkey", "ape", "apes", "monkeys", "devil", "devils", "hostile", "glaring", "snarling", "snarl", "wary", "warily", "troupe", "ass", "asshole", "gaudy", "hindquarters", "hungry", "skinny", "lean", "hungrily", "sphincter", "arsehole", "arse", "butt", "butthole", "bunghole", "buttock", "buttocks", "red", "blue", "psychedelic", "landscape", "rear", "underfed", "rectum"and "vicious" as the scenery_baboons.

To say baboon details:

say "The underfed baboons snarl and bicker, their attention focussed on [run paragraph on]";

if the baboons are boinked

begin;

say "your buttocks, the sight of which whipped them into a murderous frenzy.";

otherwise;

if the baboon clock is greater than zero

begin;

say "each other and their struggle for possession of [the baboon disputation item].";

otherwise;

say "you.";

end if;

end if;

Halfway up the Banana Tree is east of the Plateau. "You are halfway up the great banana tree; it rises to the east and descends to the west. Underneath you is a thousand feet of air, and beneath that the jungle." Instead of going up in Halfway up the Banana Tree, try going east. Instead of going down in Halfway up the Banana Tree, try going west. Instead of going north in Halfway up the Banana Tree, try entering the scenery_void. Instead of going south in Halfway up the Banana Tree, try going north.

The scenery_banana_tree2 is a backdrop in Up a Tree. The description is "The great banana tree describes a gentle arc underfoot, arching out over the void. It is easily thick enough to bear your weight, and except for the first few feet near the ground you can just walk along the trunk without needing to use your hands at all." Understand "banana", "tree", "arc", "gentle", "wide", "trunk", "great", "large", "thick", and "plant" as the scenery_banana_tree2. The printed name is "banana tree". Instead of climbing the scenery_banana_tree2, try entering the scenery_banana_tree2. The scenery_banana_tree2 can be enterable. It is enterable. Instead of entering the scenery_banana_tree2:

if the location is Halfway Up the Banana Tree, instead say "The tree extends both up and down from here.";

try going west.

The scenery_void is a backdrop. It is in the Plateau. It is in Up a Tree. The scenery_void can be enterable. It is enterable. The description is "Far, far below, the jungle stretches endlessly." Understand "void", "jungle", "thousand", "feet", "trees", "below", "beneath", "down", and "air" as the scenery_void. The printed name is "jungle". Carry out entering the scenery_void:

say "You tumble down, and down, and down, finally tearing yourself to pieces in the upper branches of the great trees below.";

end the story saying "You have fallen most spectacularly to your death".

Instead of jumping into the scenery_void, try entering the scenery_void. Instead of diving into the scenery_void, try entering the scenery_void.

Top of the Banana Tree is east of Halfway Up the Banana Tree. "This is the very top of the great banana tree, cantilevered far out over the void, which stretches a thousand feet below you. The tree descends in a gentle arc to the west." Instead of going down in Top of the Banana Tree, try going west. Instead of going north in Top of the Banana Tree, try entering the scenery_void. Instead of going south in Top of the Banana Tree, try going north. Instead of going east in Top of the Banana Tree, try going north.

Before cutting the Golden Banana of Discord when the location is Top of the Banana Tree:

If the machete is held by the player, instead try attacking the golden banana with the rusty machete;

say "You don't have anything to cut it with, but you could probably just take it instead."

Before attacking the Golden Banana of Discord with the rusty machete:

if the location is Top of the Banana Tree

begin;

say "You reach to grab the banana with your left hand while swinging the machete at it with your right. [run paragraph on]";

follow the banana-picking rule;

stop the action;

end if.

Before taking the Golden Banana of Discord when the location is Top of the Banana Tree:

follow the banana-picking rule;

stop the action.

This is the banana-picking rule:

say "As you touch the Golden Banana of Discord, pale fire erupts from it, engulfing you. [run paragraph on]";

if anything is worn by the player

begin;

let R be a random thing worn by the player;

if R is the signet ring

begin;

say "The signet ring sears into the flesh of your finger[run paragraph on]";

otherwise;

say "[The R] bursts into flame[run paragraph on]";

end if;

say ", and, shrieking, you tumble from the banana tree into the jungle far, far below.";

end the story saying "You have plunged, burning, to your death";

stop the action;

end if;

say "The baboons, howling with fear, [if the location of the baboons is not the Plateau]scuttle to the bottom of the tree and [end if]cower, shielding their eyes from the radiance, which, miraculously, does not burn you. You straighten up, grasping the banana. There is a rumble like distant thunder, and you feel the tree shake very slightly under your feet. From the southeast, you see a blue dot shoot into the air from behind the ridge to the east.";

now the nudity clock is 1;

now the banana clock is 1;

move the Golden Banana to the player;

move the scenery_hippo_dot to the location;

move the baboons to the Plateau;

stop the action.

The scenery_hippo_dot is scenery. The description is "It's a blue dot, very far off to the southeast, on a ballistic trajectory. It might be a blue hippopotamus seen from a very long way away." The printed name is "blue dot". Understand "hippo", "blue", "dot", "southeast", "ballistic", "hippopotamus" as the scenery_hippo_dot. Instead of doing anything other than examining with the scenery_hippo_dot, say "It's a very long way away.";

The scenery_hippo_far is scenery. The description is "The blue thing is definitely getting closer. It appears to be a blue hippopotamus, travelling along a very long parabola." The printed name is "blue hippo". Understand "hippo", "blue", "southeast", "ballistic", "hippopotamus" as the scenery_hippo_far. Instead of doing anything other than examining with the scenery_hippo_far, say "It's a very long way away, although closing rapidly.";

The scenery_hippo_near is scenery. The description is "The blue hippo falls towards you, its mouth wide open. It looks as if it will pass just under the banana tree." The The printed name is "blue hippo". Understand "hippo", "blue", "southeast", "ballistic", "hippopotamus", "hippo's", "open", "wide", and "mouth" as the scenery_hippo_near. Instead of doing anything other than examining with the scenery_hippo_near, say "It's still well out of reach.". Instead of jumping into or diving into the scenery_hippo_near, try jumping.

The scenery_mweru_stooping is scenery. The description is "The Mweru bird is in a power dive, aiming for the blue hippopotamus." The printed name is "Mweru bird". Understand "mweru", "bird", "roc", "yellow", and "canary" as the scenery_mweru_stooping.

Before entering the scenery_void:

if the scenery_hippo_near is in the location

begin;

say "With considerably more aplomb and confidence than you actually feel, you swan-dive into the void, clutching the Golden Banana tightly. For a heart-stopping second, you wonder if you've mistimed it, and then you hit the hippo's open mouth. With a snap, the jaws close overhead.";

move the player to Hippopotamus Interior;

stop the action;

end if.

Notes

[1]. This is safe to do, because if you are undressed and in the baboons' location, you're already dead.

[2]. For seizing the banana. Not for what you're thinking.